![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to htboot.s CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [CSRG BSD Unix] / 41BSD / 4.0.upgrade / sys / mdec|
Return to htboot.s CVS log | Up to [CSRG BSD Unix] / 41BSD / 4.0.upgrade / sys / mdec |
1.1 root 1: /*
2: * VAX tape boot block for distribution tapes
3: * works on massbus tu10/te16/tu45/tu77
4: *
5: * reads a program from a tp directory on a tape and executes it
6: * program must be stripped of the header and is loaded ``bits as is''
7: * you can return to this loader via ``ret'' as you are called ``calls $0,ent''
8: */
9: .set RELOC,0x70000
10: /* a.out defines */
11: .set HDRSIZ,040 /* size of file header for VAX */
12: .set MAGIC,0410 /* file type id in header */
13: .set TSIZ,4 /* text size */
14: .set DSIZ,8 /* data size */
15: .set BSIZ,12 /* bss size */
16: .set TENT,024 /* task header entry loc */
17: /* tp directory definitions */
18: .set FILSIZ,38 /* tp direc offset for file size */
19: .set BNUM,44 /* tp dir offset for start block no. */
20: .set ENTSIZ,64 /* size of 1 TP dir entry, bytes */
21: .set PTHSIZ,32 /* size of TP path name, bytes */
22: .set BLKSIZ,512 /* tape block size, bytes */
23: .set NUMDIR,24 /* no. of dir blocks on tape */
24: .set ENTBLK,8 /* no. of dir entries per tape block */
25: /* processor registers and bits */
26: .set RXCS,32
27: .set RXDB,33
28: .set TXCS,34
29: .set TXDB,35
30: .set RXCS_DONE,0x80
31: .set TXCS_RDY,0x80
32: .set TXCS_pr,7 /* bit position of TXCS ready bit */
33: .set RXCS_pd,7 /* bit position of RXCS done bit */
34: /* MBA registers */
35: .set MBA_CSR,0 /* configuration and status register */
36: .set MBA_CR,4 /* MBA control reg */
37: .set MBA_SR,8 /* MBA status reg */
38: .set MBA_VAR,12 /* MBA virt addr reg */
39: .set MBA_BCR,16 /* MBA byte count reg */
40: .set MBA_MAP,0x800 /* start of MBA map reg's */
41: .set MRV,0x80000000
42: /* TE16/TU45/TU77 mba registers */
43: .set HTCS1,0 /* HT control 1 reg */
44: .set HTDS,4 /* status reg */
45: .set HTER,8 /* error reg */
46: .set HTAS,16 /* attention summary */
47: .set HTFC,20 /* frame count */
48: .set HTTC,36 /* HT tape control */
49: /* HT commands */
50: .set GO,1 /* GO bit */
51: .set HT_REW,6 /* rewind, on-line */
52: .set HT_DCLR,010 /* drive clear */
53: .set HT_SREV,032 /* space reverse */
54: .set HT_RCOM,070 /* read forward */
55: /* HT bits */
56: .set ERR,040000 /* composite error bit in status reg */
57: .set TCHAR,012300 /* unit 0, odd parity, PDP11, 1600 BPI NRZ, */
58: /* abort on error - for tape controller */
59: .set DRDY,0200 /* HT/drive ready in status reg */
60: .set HT_pd,7 /* bit position of HT DRDY bit */
61: .set HT_pe,14 /* bit position of HT ERROR bit */
62: /* local stack variables */
63: .set tapa,-4 /* desired tape addr */
64: .set mtapa,-8 /* current tape addr */
65: .set name,-8-PTHSIZ /* operator-typed file name */
66: /* register usage */
67: .set rMBA,r10
68: .set rHT,r11
69:
70: /* initialization */
71: init:
72: mull2 $0x80,%rHT
73: addl2 $0x400,%rHT
74: addl2 %rMBA,%rHT
75: movl $RELOC,fp /* core loc to which to move this program */
76: addl3 $name,fp,sp /* set stack pointer, leaving room for locals */
77: clrl r0
78: 1:
79: movc3 $end,(r0),(fp) /* move boot up to relocated position */
80: jmp start+RELOC
81: start:
82: movl $1,MBA_CR(%rMBA) /* MBA init */
83: movl $TCHAR,HTTC(%rHT) /* drive no., etc. */
84: movl $HT_DCLR+GO,HTCS1(%rHT) /* drive clear */
85: bsbw rew /* rewind input tape */
86: movab name(fp),r4 /* start of filename storage */
87: movzbl $'=,r0 /* prompt character */
88: bsbw putc /* output char to main console */
89: /* read in a file name */
90: movl r4,r1 /* loc at which to store file name */
91: nxtc:
92: bsbw getc /* get input char's in file name */
93: cmpb r0,$012 /* terminator ? */
94: beql nullc
95: movb r0,(r1)+
96: brb nxtc
97: nullc:
98: subl3 r4,r1,r9 /* size of path name */
99: beql start /* dumb operator */
100: clrb (r1)+
101: incl r9
102: /* user-specified TP filename has been stored at name(fp) */
103: /* read in entire tp directory contents into low core */
104: dirred:
105: movl $8,tapa(fp) /* tp directory starts at block 8 */
106: movl $(NUMDIR*BLKSIZ),r6 /* no. bytes in total dir */
107: bsbw taper /* read no. bytes indicated */
108: /* search entire directory for user-specified file name */
109: clrl r5 /* dir buff loc = 0 */
110: nxtdir:
111: cmpc3 r9,(r5),(r4) /* see if dir entry matches filename */
112: beql fndfil /* found match */
113: acbl $NUMDIR*BLKSIZ-1,$ENTSIZ,r5,nxtdir
114: /* see if done with tp dir */
115: brw start /* entry not in directory; start over */
116: /* found desired tp dir entry */
117: fndfil:
118: movzwl BNUM(r5),tapa(fp) /* start block no., 2 bytes */
119: addl2 $7,tapa(fp) /* skip 7 boot blocks */
120: movzwl FILSIZ(r5),r6 /* low 2 bytes file size */
121: insv FILSIZ-1(r5),$16,$8,r6 /* file size, high byte */
122: cmpl r6,$RELOC-512 /* check if file fits below stack */
123: blss filok /* file o.k. */
124: brw start /* file too large */
125: /* time to read in desired file from tape */
126: filok:
127: movl r6,r7 /* save r6 */
128: bsbb taper
129: bsbw rew
130: /* clear core */
131: subl3 r7,$RELOC-4,r0 /* no. bytes to clear */
132: 1:
133: clrb (r7)+
134: sobgtr r0,1b
135: /* time to jump to start of file & execute */
136: addl3 $20,fp,ap
137: clrl r5
138: calls $0,(r5)
139: brw start
140: /* taper: movcTAPE (r6),tapa(fp),0 */
141: rew2:
142: bsbb rew /* beginning of tape */
143: taper0:
144: bsbb rrec /* advance 1 block; never want blk0 */
145: taper:
146: clrl r0 /* page no. */
147: cmpl mtapa(fp),tapa(fp) /* current position .vs. desired */
148: bgtr rew2
149: blss taper0
150: 1:
151: bsbb rrec
152: acbl $1,$-BLKSIZ,r6,1b
153: rsb
154: /* rew: rewind the tape */
155: rew:
156: clrl mtapa(fp) /* current position */
157: movl $HT_REW+GO,HTCS1(%rHT) /* rewind */
158: rsb
159: /* rrec: read 1 block from mag tape into page (r0) */
160: rrec:
161: /* pushl r0; movzbl $'r,r0; bsbw putc; movl (sp)+,r0; */
162: movl HTDS(%rHT),r2
163: bbc $HT_pd,r2,rrec /* HT & drive ready ? */
164: movl $-BLKSIZ,MBA_BCR(%rMBA)
165: bisl3 $MRV,r0,MBA_MAP(%rMBA)
166: clrl MBA_VAR(%rMBA)
167: movl $HT_RCOM+GO,HTCS1(%rHT) /* read forward */
168: 1:
169: movl HTDS(%rHT),r2
170: bbc $HT_pd,r2,1b
171: movl HTER(%rHT),r2
172: bbc $HT_pe,r2,2f /* any read errors ? */
173: clrl HTDS(%rHT) /* clear status - try to recover */
174: mnegl $1,HTFC(%rHT) /* frame count for backspace */
175: movl $HT_SREV+GO,HTCS1(%rHT) /* space reverse */
176: brb rrec
177: 2:
178: incl r0 /* next page no. */
179: incl mtapa(fp) /* mag tape block position */
180: rsb
181: getc:
182: mfpr $RXCS,r0
183: bbc $RXCS_pd,r0,getc /* receiver ready ? */
184: mfpr $RXDB,r0
185: extzv $0,$7,r0,r0
186: cmpb r0,$015
187: bneq putc
188: bsbb putc
189: movb $0,r0
190: bsbb putc
191: movb $012,r0
192: putc:
193: mfpr $TXCS,r2
194: bbc $TXCS_pr,r2,putc /* transmitter ready ? */
195: extzv $0,$7,r0,r0
196: mtpr r0,$TXDB
197: rsb
198: end:
This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.