Return to mtboot.s CVS log

Up to [CSRG BSD Unix] / 41BSD / 4.0.upgrade / sys / mdec

Annotation of 41BSD/4.0.upgrade/sys/mdec/mtboot.s, revision 1.1

1.1     ! root        1: /*
        !             2:  * VAX tape boot block for distribution tapes
        !             3:  * works on massbus tu78
        !             4:  *
        !             5:  * reads a program from a tp directory on a tape and executes it
        !             6:  * program must be stripped of the header and is loaded ``bits as is''
        !             7:  * you can return to this loader via ``ret'' as you are called ``calls $0,ent''
        !             8:  */
        !             9:        .set    RELOC,0x70000
        !            10: /* a.out defines */
        !            11:        .set    HDRSIZ,040      /* size of file header for VAX */
        !            12:        .set    MAGIC,0410      /* file type id in header */
        !            13:        .set    TSIZ,4          /* text size */
        !            14:        .set    DSIZ,8          /* data size */
        !            15:        .set    BSIZ,12         /* bss size */
        !            16:        .set    TENT,024        /* task header entry loc */
        !            17: /* tp directory definitions */
        !            18:        .set    FILSIZ,38       /* tp direc offset for file size */
        !            19:        .set    BNUM,44         /* tp dir offset for start block no. */
        !            20:        .set    ENTSIZ,64       /* size of 1 TP dir entry, bytes */
        !            21:        .set    PTHSIZ,32       /* size of TP path name, bytes */
        !            22:        .set    BLKSIZ,512      /* tape block size, bytes */
        !            23:        .set    NUMDIR,24       /* no. of dir blocks on tape */
        !            24:        .set    ENTBLK,8        /* no. of dir entries per tape block */
        !            25: /* processor registers and bits */
        !            26:        .set    RXCS,32
        !            27:        .set    RXDB,33
        !            28:        .set    TXCS,34
        !            29:        .set    TXDB,35
        !            30:        .set    RXCS_DONE,0x80
        !            31:        .set    TXCS_RDY,0x80
        !            32:        .set    TXCS_pr,7       /* bit position of TXCS ready bit */
        !            33:        .set    RXCS_pd,7       /* bit position of RXCS done bit */
        !            34: /* MBA registers */
        !            35:        .set    MBA_CSR,0       /* configuration and status register */
        !            36:        .set    MBA_CR,4        /* MBA control reg */
        !            37:        .set    MBA_SR,8        /* MBA status reg */
        !            38:        .set    MBA_VAR,12      /* MBA virt addr reg */
        !            39:        .set    MBA_BCR,16      /* MBA byte count reg */
        !            40:        .set    MBA_MAP,0x800   /* start of MBA map reg's */
        !            41:        .set    MRV,0x80000000
        !            42:        .set    MBA_pdtc,13     /* position of data transfer complete bit */
        !            43: /* TU78 mba registers */
        !            44:        .set    MTCS,0          /* MT control reg */
        !            45:        .set    MTER,4          /* error reg */
        !            46:        .set    MTCA,8          /* command address */
        !            47:        .set    MTAS,16         /* attention summary */
        !            48:        .set    MTBC,20         /* byte count */
        !            49:        .set    MTNER,44        /* non-data transfer error register */
        !            50:        .set    MTNCS,48        /* non-data transfer command register */
        !            51:        .set    MTID,68         /* MT internal data */
        !            52: /* MT commands */
        !            53:        .set    GO,1            /* GO bit */
        !            54:        .set    MT_REW,6        /* rewind, on-line */
        !            55:        .set    MT_SREV,022     /* space reverse */
        !            56:        .set    MT_RCOM,070     /* read forward */
        !            57: /* MT bits */
        !            58:        .set    CCLR,040000     /* controller clear */
        !            59:        .set    MT_pr,15        /* bit position of MT TMRDY bit */
        !            60: /* local stack variables */
        !            61:        .set    tapa,-4         /* desired tape addr */
        !            62:        .set    mtapa,-8        /* current tape addr */
        !            63:        .set    name,-8-PTHSIZ  /* operator-typed file name */
        !            64: /* register usage */
        !            65:        .set    rMBA,r10
        !            66:        .set    rMT,r11
        !            67: 
        !            68: /* initialization */
        !            69: init:
        !            70:        mull2   $0x80,%rMT
        !            71:        addl2   $0x400,%rMT
        !            72:        addl2   %rMBA,%rMT
        !            73:        movl    $RELOC,fp       /* core loc to which to move this program */
        !            74:        addl3   $name,fp,sp     /* set stack pointer, leaving room for locals */
        !            75:        clrl    r0
        !            76: 1:
        !            77:        movc3   $end,(r0),(fp)  /* move boot up to relocated position */
        !            78:        jmp     start+RELOC
        !            79: start:
        !            80:        movl    $1,MBA_CR(%rMBA)        /* MBA init */
        !            81:        movl    $CCLR,MTID(%rMT)        /* controller clear */
        !            82:        movl    $250,r0
        !            83: 0:     sobgtr  r0,0b
        !            84: 0:     movl    MTID(%rMT),r0           /* wait for ready */
        !            85:        bbc     $MT_pr,r0,0b
        !            86:        bsbw    rew                     /* rewind input tape */
        !            87:        movab   name(fp),r4             /* start of filename storage */
        !            88:        movzbl  $'=,r0                  /* prompt character */
        !            89:        bsbw    putc                    /* output char to main console */
        !            90: /* read in a file name */
        !            91:        movl    r4,r1                   /* loc at which to store file name */
        !            92: nxtc:
        !            93:        bsbw    getc                    /* get input char's in file name */
        !            94:        cmpb    r0,$012                 /* terminator ? */
        !            95:        beql    nullc
        !            96:        movb    r0,(r1)+
        !            97:        brb     nxtc
        !            98: nullc:
        !            99:        subl3   r4,r1,r9                /* size of path name */
        !           100:        beql    start                   /* dumb operator */
        !           101:        clrb    (r1)+
        !           102:        incl    r9
        !           103: /* user-specified TP filename has been stored at name(fp) */
        !           104: /* read in entire tp directory contents into low core */
        !           105: dirred:
        !           106:        movl    $8,tapa(fp)             /* tp directory starts at block 8 */
        !           107:        movl    $(NUMDIR*BLKSIZ),r6     /* no. bytes in total dir */
        !           108:        bsbw    taper                   /* read no. bytes indicated */
        !           109: /* search entire directory for user-specified file name */
        !           110:        clrl    r5                      /* dir buff loc = 0 */
        !           111: nxtdir:
        !           112:        cmpc3   r9,(r5),(r4)            /* see if dir entry matches filename */
        !           113:        beql    fndfil                  /* found match */
        !           114:        acbl    $NUMDIR*BLKSIZ-1,$ENTSIZ,r5,nxtdir
        !           115:                                        /* see if done with tp dir */
        !           116:        brw     start                   /* entry not in directory; start over */
        !           117: /* found desired tp dir entry */
        !           118: fndfil:
        !           119:        movzwl  BNUM(r5),tapa(fp)       /* start block no., 2 bytes */
        !           120:        addl2   $7,tapa(fp)             /* skip 7 boot blocks */
        !           121:        movzwl  FILSIZ(r5),r6           /* low 2 bytes file size */
        !           122:        insv    FILSIZ-1(r5),$16,$8,r6  /* file size, high byte */
        !           123:        cmpl    r6,$RELOC-512           /* check if file fits below stack */
        !           124:        blss    filok                   /* file o.k. */
        !           125:        brw     start                   /* file too large */
        !           126: /* time to read in desired file from tape */
        !           127: filok:
        !           128:        movl    r6,r7                   /* save r6 */
        !           129:        bsbb    taper
        !           130:        bsbw    rew
        !           131: /* clear core */
        !           132:        subl3   r7,$RELOC-4,r0          /* no. bytes to clear */
        !           133: 1:
        !           134:        clrb    (r7)+
        !           135:        sobgtr  r0,1b
        !           136: /* time to jump to start of file & execute */
        !           137:        addl3   $20,fp,ap
        !           138:        clrl    r5
        !           139:        calls   $0,(r5)
        !           140:        brw     start
        !           141: /* taper: movcTAPE (r6),tapa(fp),0 */
        !           142: rew2:
        !           143:        bsbb    rew                     /* beginning of tape */
        !           144: taper0:
        !           145:        bsbb    rrec                    /* advance 1 block; never want blk0 */
        !           146: taper:
        !           147:        clrl    r0                      /* page no. */
        !           148:        cmpl    mtapa(fp),tapa(fp)      /* current position .vs. desired */
        !           149:        bgtr    rew2
        !           150:        blss    taper0
        !           151: 1:
        !           152:        bsbb    rrec
        !           153:        acbl    $1,$-BLKSIZ,r6,1b
        !           154:        rsb
        !           155: /* rew: rewind the tape */
        !           156: rew:
        !           157:        clrl    mtapa(fp)               /* current position */
        !           158:        clrl    MTNER(%rMT)             /* clear error */
        !           159:        movl    $MT_REW+GO,MTNCS(%rMT)  /* rewind */
        !           160: 1:
        !           161:        movl    MTNER(%rMT),r2          /* done? */
        !           162:        movl    MTAS(%rMT),MTAS(%rMT)
        !           163:        bicl2   $~077,r2
        !           164:        cmpl    $1,r2
        !           165:        bneq    1b
        !           166:        rsb
        !           167: /* rrec: read 1 block from mag tape into page (r0) */
        !           168: rrec:
        !           169:        /* pushl r0; movzbl $'r,r0; bsbw putc; movl (sp)+,r0; */
        !           170: rrec2:
        !           171:        movl    $-BLKSIZ,MBA_BCR(%rMBA)
        !           172:        movl    $BLKSIZ,MTBC(%rMT)
        !           173:        bisl3   $MRV,r0,MBA_MAP(%rMBA) 
        !           174:        clrl    MBA_VAR(%rMBA)
        !           175:        clrl    MTER(%rMT)
        !           176:        movl    MBA_SR(%rMBA),MBA_SR(%rMBA)
        !           177:        movzbl  $4,MTCA(%rMT)           /* drive zero, one record */
        !           178:        movl    $MT_RCOM+GO,MTCS(%rMT)  /* read forward */
        !           179: 1:
        !           180:        movl    MTER(%rMT),r2
        !           181:        bicl2   $~077,r2
        !           182:        beql    1b
        !           183:        movl    $1000,r1
        !           184: 0:     sobgtr  r1,0b
        !           185:        cmpl    $1,r2                   /* any read errors ? */
        !           186:        beql    2f
        !           187:         pushl r0; movzbl $'b,r0; bsbw putc; movl (sp)+,r0; 
        !           188:        brb     rrec2
        !           189: 2:
        !           190:        incl    r0                      /* next page no. */
        !           191:        incl    mtapa(fp)               /* mag tape block position */
        !           192:        rsb
        !           193: getc:
        !           194:        mfpr    $RXCS,r0
        !           195:        bbc     $RXCS_pd,r0,getc        /* receiver ready ? */
        !           196:        mfpr    $RXDB,r0
        !           197:        extzv   $0,$7,r0,r0
        !           198:        cmpb    r0,$015
        !           199:        bneq    putc
        !           200:        bsbb    putc
        !           201:        movb    $0,r0
        !           202:        bsbb    putc
        !           203:        movb    $012,r0
        !           204: putc:
        !           205:        mfpr    $TXCS,r2
        !           206:        bbc     $TXCS_pr,r2,putc        /* transmitter ready ? */
        !           207:        extzv   $0,$7,r0,r0
        !           208:        mtpr    r0,$TXDB
        !           209:        rsb
        !           210: end:

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.