Return to urem.s CVS log

Up to [CSRG BSD Unix] / 42BSD / lib / libc / vax / gen

Annotation of 42BSD/lib/libc/vax/gen/urem.s, revision 1.1

1.1     ! root        1: /*     urem.s  4.2     83/06/27        */
        !             2: 
        !             3: /*
        !             4:  * urem - unsigned remainder for vax-11
        !             5:  *
        !             6:  * arguments: dividend, divisor
        !             7:  * result: remainder
        !             8:  * uses r0-r2
        !             9:  *
        !            10:  * if 1 < divisor <= 2147483647, zero-extend the dividend
        !            11:  * to 64 bits and let ediv do the work.  If the divisor is 1,
        !            12:  * ediv will overflow if bit 31 of the dividend is on, so
        !            13:  * just return 0.  If the divisor is 0, do the ediv also,
        !            14:  * so it will generate the proper exception.  All other values
        !            15:  * of the divisor have bit 31 on: in this case the remainder
        !            16:  * must be the dividend if divisor > dividend, and the dividend
        !            17:  * minus the divisor otherwise.  The comparison must be unsigned.
        !            18:  */
        !            19: #include "DEFS.h"
        !            20: 
        !            21: ASENTRY(urem)
        !            22:        movl    4(ap),r0        /* dividend */
        !            23:        movl    8(ap),r2        /* divisor */
        !            24:        jeql    1f              /* if divisor=0, force exception */
        !            25:        cmpl    r2,$1           /* if divisor <= 1 (signed), */
        !            26:        jleq    2f              /*  no division is necessary */
        !            27: 1:
        !            28:        clrl    r1              /* zero-extend the dividend */
        !            29:        ediv    r2,r0,r2,r0     /* divide.  q->r2 (discarded), r->r0 */
        !            30:        ret
        !            31: 2:
        !            32:        jneq    1f              /* if divisor=1, return 0 */
        !            33:        clrl    r0              /*  (because doing the divide will overflow */
        !            34:        ret                     /*  if the dividend has its high bit on) */
        !            35: 1:
        !            36:        cmpl    r0,r2           /* if dividend < divisor (unsigned) */
        !            37:        jlssu   1f              /*  remainder is dividend */
        !            38:        subl2   r2,r0           /*  else remainder is dividend - divisor */
        !            39: 1:
        !            40:        ret

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.