Return to tmboot.s CVS log

Up to [CSRG BSD Unix] / 42BSD / sys / mdec

Annotation of 42BSD/sys/mdec/tmboot.s, revision 1.1

1.1     ! root        1: /*     tmboot.s        6.1     83/07/29        */
        !             2: 
        !             3: /*
        !             4:  * VAX tape boot block for distribution tapes
        !             5:  * works on unibus tm03
        !             6:  *
        !             7:  * reads a program from a tp directory on a tape and executes it
        !             8:  * program must be stripped of the header and is loaded ``bits as is''
        !             9:  * you can return to this loader via ``ret'' as you are called ``calls $0,ent''
        !            10:  */
        !            11:        .set    RELOC,0x70000
        !            12: /* a.out defines */
        !            13:        .set    HDRSIZ,040      /* size of file header for VAX */
        !            14:        .set    MAGIC,0410      /* file type id in header */
        !            15:        .set    TSIZ,4          /* text size */
        !            16:        .set    DSIZ,8          /* data size */
        !            17:        .set    BSIZ,12         /* bss size */
        !            18:        .set    TENT,024        /* task header entry loc */
        !            19: /*  tp directory definitions */
        !            20:        .set    FILSIZ,38       /* tp direc offset for file size */
        !            21:        .set    BNUM,44         /* tp dir offset for start block no. */
        !            22:        .set    ENTSIZ,64       /* size of 1 TP dir entry, bytes */
        !            23:        .set    PTHSIZ,32       /* size of TP path name, bytes */
        !            24:        .set    BLKSIZ,512      /* tape block size, bytes */
        !            25:        .set    NUMDIR,24       /* no. of dir blocks on tape */
        !            26:        .set    ENTBLK,8        /* no. of dir entries per tape block */
        !            27: /* processor registers and bits */
        !            28:        .set    RXCS,32
        !            29:        .set    RXDB,33
        !            30:        .set    TXCS,34
        !            31:        .set    TXDB,35
        !            32:        .set    RXCS_DONE,0x80
        !            33:        .set    TXCS_RDY,0x80
        !            34:        .set    TXCS_pr,7       /* bit position of TXCS ready bit */
        !            35:        .set    RXCS_pd,7       /* bit position of RXCS done bit */
        !            36: /* UBA registers */
        !            37:        .set    UBA_DPR1,68
        !            38:        .set    UBA_MAP,2048
        !            39:        .set    BNE,0x80000000
        !            40:        .set    MRV,0x80000000
        !            41:        .set    MR_BDP1,0x200000
        !            42: /* TM UBA registers */
        !            43:        .set    TMER,0
        !            44:        .set    TMCS,2
        !            45:        .set    TMBC,4
        !            46:        .set    TMBA,6
        !            47: /* TM commands and bits */
        !            48:        .set    GO,1
        !            49:        .set    TM_REW,016
        !            50:        .set    TM_RCOM,02
        !            51:        .set    TM_SREV,012
        !            52:        .set    TM_DCLR,010000
        !            53:        .set    TM_crdy,7
        !            54:        .set    TM_gapsd,3
        !            55:        .set    TMDENS,0                /* 1600 bpi */
        !            56: /* local stack variables */
        !            57:        .set    tapa,-4         /* desired tape addr */
        !            58:        .set    mtapa,-8        /* current tape addr */
        !            59:        .set    name,-8-PTHSIZ  /* operator-typed file name */
        !            60: /* register usage */
        !            61:        .set    rUBA,r10
        !            62:        .set    rTM,r11
        !            63: /* ===== */
        !            64: 
        !            65: /* initialization */
        !            66: init:
        !            67:        movl    $RELOC,fp       /* core loc to which to move this program */
        !            68:        addl3   $name,fp,sp     /* set stack pointer; leave room for locals */
        !            69:        clrl    r0
        !            70: 1:
        !            71:        movc3   $end,(r0),(fp)  /* move boot up to relocated position */
        !            72:        jmp     start+RELOC
        !            73: start:
        !            74:        bsbw    rew                     /* rewind input tape */
        !            75:        movab   name(fp),r4             /* start of filename storage */
        !            76:        movzbl  $'=,r0                  /* prompt character */
        !            77:        bsbw    putc                    /* output char to main console */
        !            78: /* read in a file name */
        !            79:        movl    r4,r1                   /* loc at which to store file name */
        !            80: nxtc:
        !            81:        bsbw    getc                    /* get input char's in file name */
        !            82:        cmpb    r0,$012                 /* terminator ? */
        !            83:        beql    nullc
        !            84:        movb    r0,(r1)+
        !            85:        brb     nxtc
        !            86: nullc:
        !            87:        subl3   r4,r1,r9                /* size of path name */
        !            88:        beql    start                   /* dumb operator */
        !            89:        clrb    (r1)+
        !            90:        incl    r9
        !            91: /* user-specified TP filename has been stored at name(fp) */
        !            92: /* read in entire tp directory contents into low core */
        !            93: dirred:
        !            94:        movl    $8,tapa(fp)             /* tp directory starts at block 8 */
        !            95:        movl    $(NUMDIR*BLKSIZ),r6     /* no. bytes in total dir */
        !            96:        bsbw    taper                   /* read no. bytes indicated */
        !            97: /* search entire directory for user-specified file name */
        !            98:        clrl    r5                      /* dir buff loc = 0 */
        !            99: nxtdir:
        !           100:        cmpc3   r9,(r5),(r4)            /* see if dir entry matches filename */
        !           101:        beql    fndfil                  /* found match */
        !           102:        acbl    $NUMDIR*BLKSIZ-1,$ENTSIZ,r5,nxtdir
        !           103:                                        /* see if done with tp dir */
        !           104:        brw     start                   /* entry not in directory; start over */
        !           105: /* found desired tp dir entry */
        !           106: fndfil:
        !           107:        movzwl  BNUM(r5),tapa(fp)       /* start block no., 2 bytes */
        !           108:        addl2   $7,tapa(fp)             /* skip 7 boot blocks */
        !           109:        movzwl  FILSIZ(r5),r6           /* low 2 bytes file size */
        !           110:        insv    FILSIZ-1(r5),$16,$8,r6  /* file size, high byte */
        !           111:        cmpl    r6,$RELOC-512           /* check if file fits below stack */
        !           112:        blss    filok                   /* file o.k. */
        !           113:        brw     start                   /* file too large */
        !           114: /* time to read in desired file from tape */
        !           115: filok:
        !           116:        movl    r6,r7                   /* save r6 */
        !           117:        bsbb    taper
        !           118:        bsbw    rew
        !           119: /* clear core */
        !           120:        subl3   r7,$RELOC-4,r0          /* no. bytes to clear */
        !           121: 1:
        !           122:        clrb    (r7)+
        !           123:        sobgtr  r0,1b
        !           124: /* time to jump to start of file & execute */
        !           125:        addl3   $20,fp,ap
        !           126:        clrl    r5
        !           127:        calls   $0,(r5)
        !           128:        brw     start
        !           129: /* taper: movcTAPE (r6),tapa(fp),0 */
        !           130: rew2:
        !           131:        bsbb    rew                     /* beginning of tape */
        !           132: taper0:
        !           133:        bsbb    rrec                    /* advance 1 block; never want blk 0 */
        !           134: taper:
        !           135:        clrl    r0                      /* page no. */
        !           136:        cmpl    mtapa(fp),tapa(fp)      /* current position .vs. desired */
        !           137:        bgtr    rew2
        !           138:        blss    taper0
        !           139: 1:
        !           140:        bsbb    rrec
        !           141:        acbl    $1,$-BLKSIZ,r6,1b
        !           142:        rsb
        !           143: /* rew: rewind the tape */
        !           144: rew:
        !           145:        clrl    mtapa(fp)               /* current position */
        !           146:        movw    $TM_REW+TMDENS+GO,TMCS(%rTM)
        !           147:        rsb
        !           148: /* rrec: read 1 block from mag tape into page (r0) */
        !           149: rrec:
        !           150:        /* pushl r0; movzbl $'r,r0; bsbw putc; movl (sp)+,r0; */
        !           151:        jsb     tmquiet
        !           152:        movw    $-BLKSIZ,TMBC(%rTM)
        !           153:        bisl3   $MRV|MR_BDP1,r0,UBA_MAP(%rUBA)
        !           154:        movw    $0,TMBA(%rTM)
        !           155:        movw    $TM_RCOM+TMDENS+GO,TMCS(%rTM)
        !           156:        jsb     tmquiet
        !           157:        bisl2   $BNE,UBA_DPR1(%rUBA)
        !           158:        tstw    TMER(%rTM)
        !           159:        jgeq    2f
        !           160:        mnegw   $1,TMBC(%rTM)
        !           161:        movw    $TM_SREV+TMDENS+GO,TMCS(%rTM)
        !           162:        jmp     rrec
        !           163: 2:
        !           164:        incl    r0                      /* next page no. */
        !           165:        incl    mtapa(fp)               /* mag tape block position */
        !           166:        rsb
        !           167: getc:
        !           168:        mfpr    $RXCS,r0
        !           169:        bbc     $RXCS_pd,r0,getc        /* receiver ready ? */
        !           170:        mfpr    $RXDB,r0
        !           171:        extzv   $0,$7,r0,r0
        !           172:        cmpb    r0,$015
        !           173:        bneq    putc
        !           174:        bsbb    putc
        !           175:        movb    $0,r0
        !           176:        bsbb    putc
        !           177:        movb    $012,r0
        !           178: putc:
        !           179:        mfpr    $TXCS,r2
        !           180:        bbc     $TXCS_pr,r2,putc        /* transmitter ready ? */
        !           181:        extzv   $0,$7,r0,r0
        !           182:        mtpr    r0,$TXDB
        !           183:        rsb
        !           184: tmquiet:
        !           185:        movw    TMCS(%rTM),r2
        !           186:        bbc     $TM_crdy,r2,tmquiet
        !           187: 1:
        !           188:        movw    TMER(%rTM),r2
        !           189:        blbc    r2,1b                   /* low bit == TUR */
        !           190:        bbs     $TM_gapsd,r2,1b
        !           191:        rsb
        !           192: end:

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.