Return to bzero.s CVS log

Up to [CSRG BSD Unix] / 43BSDReno / lib / libc / hp300 / string

Annotation of 43BSDReno/lib/libc/hp300/string/bzero.s, revision 1.1.1.1

1.1       root        1: /*-
                      2:  * Copyright (c) 1990 The Regents of the University of California.
                      3:  * All rights reserved.
                      4:  *
                      5:  * This code is derived from software contributed to Berkeley by
                      6:  * the Systems Programming Group of the University of Utah Computer
                      7:  * Science Department.
                      8:  *
                      9:  * Redistribution and use in source and binary forms are permitted
                     10:  * provided that: (1) source distributions retain this entire copyright
                     11:  * notice and comment, and (2) distributions including binaries display
                     12:  * the following acknowledgement:  ``This product includes software
                     13:  * developed by the University of California, Berkeley and its contributors''
                     14:  * in the documentation or other materials provided with the distribution
                     15:  * and in all advertising materials mentioning features or use of this
                     16:  * software. Neither the name of the University nor the names of its
                     17:  * contributors may be used to endorse or promote products derived
                     18:  * from this software without specific prior written permission.
                     19:  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
                     20:  * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
                     21:  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
                     22:  */
                     23: 
                     24: #if defined(LIBC_SCCS) && !defined(lint)
                     25:        .asciz "@(#)bzero.s     5.1 (Berkeley) 5/12/90"
                     26: #endif /* LIBC_SCCS and not lint */
                     27: 
                     28: #include "DEFS.h"
                     29: 
                     30: /*
                     31:  * This is probably not the best we can do, but it is still much
                     32:  * faster than the C version in the portable gen directory.
                     33:  *
                     34:  * Things that might help:
                     35:  *     - unroll the longword loop (might not be good for a 68020)
                     36:  *     - longword, as opposed to word, align when possible (only on the 68020)
                     37:  *     - use nested DBcc instructions or use one and limit size to 64K
                     38:  */
                     39: ENTRY(bzero)
                     40:        movl    sp@(4),a0       /* destination */
                     41:        movl    sp@(8),d0       /* count */
                     42:        jeq     bzdone          /* nothing to do */
                     43:        movl    a0,d1
                     44:        btst    #0,d1           /* address odd? */
                     45:        jeq     bzeven          /* no, skip alignment */
                     46:        clrb    a0@+            /* yes, clear a byte */
                     47:        subql   #1,d0           /* adjust count */
                     48:        jeq     bzdone          /* if zero, all done */
                     49: bzeven:
                     50:        movl    d0,d1
                     51:        lsrl    #2,d1           /* convert to longword count */
                     52:        jeq     bzbloop         /* no longwords, skip loop */
                     53: bzlloop:
                     54:        clrl    a0@+            /* clear a longword */
                     55:        subql   #1,d1           /* adjust count */
                     56:        jne     bzlloop         /* still more, keep going */
                     57:        andl    #3,d0           /* what remains */
                     58:        jeq     bzdone          /* nothing, all done */
                     59: bzbloop:
                     60:        clrb    a0@+            /* clear a byte */
                     61:        subql   #1,d0           /* adjust count */
                     62:        jne     bzbloop         /* still more, keep going */
                     63: bzdone:
                     64:        rts

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.