Return to strncat.s CVS log

Up to [CSRG BSD Unix] / 43BSDReno / lib / libc / vax / string

Annotation of 43BSDReno/lib/libc/vax/string/strncat.s, revision 1.1.1.1

1.1       root        1: /*
                      2:  * Copyright (c) 1983 Regents of the University of California.
                      3:  * All rights reserved.
                      4:  *
                      5:  * Redistribution and use in source and binary forms are permitted
                      6:  * provided that: (1) source distributions retain this entire copyright
                      7:  * notice and comment, and (2) distributions including binaries display
                      8:  * the following acknowledgement:  ``This product includes software
                      9:  * developed by the University of California, Berkeley and its contributors''
                     10:  * in the documentation or other materials provided with the distribution
                     11:  * and in all advertising materials mentioning features or use of this
                     12:  * software. Neither the name of the University nor the names of its
                     13:  * contributors may be used to endorse or promote products derived
                     14:  * from this software without specific prior written permission.
                     15:  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
                     16:  * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
                     17:  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
                     18:  */
                     19: 
                     20: #if defined(LIBC_SCCS) && !defined(lint)
                     21:        .asciz "@(#)strncat.s   5.6 (Berkeley) 6/1/90"
                     22: #endif /* LIBC_SCCS and not lint */
                     23: 
                     24: /*
                     25:  * Concatenate string s2 on the end of s1
                     26:  * and return the base of s1.  The parameter
                     27:  * n is the maximum length of string s2 to
                     28:  * concatenate.
                     29:  *
                     30:  * char *
                     31:  * strncat(s1, s2, n)
                     32:  *     char *s1, *s2;
                     33:  *     int n;
                     34:  */
                     35: #include "DEFS.h"
                     36: 
                     37: ENTRY(strncat, R6)
                     38:        movl    12(ap),r6       # r6 = n
                     39:        bleq    done            # n <= 0
                     40:        movl    4(ap),r3        # r3 = s1
                     41:        movl    r3,r1
                     42: 0:
                     43:        locc    $0,$65535,(r1)
                     44:        beql    0b
                     45:        movl    r1,r3           # r3 = index(s1, '\0');
                     46:        movl    8(ap),r1        # r1 = s2
                     47: 1:
                     48:        movzwl  $65535,r2       # r2 = bytes in first chunk
                     49:        cmpl    r6,r2           # r2 = min(bytes in chunk, n);
                     50:        jgeq    2f
                     51:        movl    r6,r2
                     52: 2:
                     53:        subl2   r2,r6           # update n
                     54:        locc    $0,r2,(r1)      # '\0' found?
                     55:        jneq    3f
                     56:        subl2   r2,r1           # back up pointer updated by locc
                     57:        movc3   r2,(r1),(r3)    # copy in next piece
                     58:        tstl    r6              # run out of space?
                     59:        jneq    1b
                     60:        clrb    (r3)            # force '\0' termination
                     61:        jbr     done
                     62: 3:
                     63:        subl2   r0,r2           # r2 = number of bytes to move
                     64:        subl2   r2,r1           # back up pointer updated by locc
                     65:        incl    r2              # copy '\0' as well
                     66:        movc3   r2,(r1),(r3)    # copy in last piece
                     67: done:
                     68:        movl    4(ap),r0        # return s1
                     69:        ret

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.