Return to strncpy.s CVS log

Up to [CSRG BSD Unix] / 43BSDReno / lib / libc / vax / string

Annotation of 43BSDReno/lib/libc/vax/string/strncpy.s, revision 1.1.1.1

1.1       root        1: /*
                      2:  * Copyright (c) 1983 Regents of the University of California.
                      3:  * All rights reserved.
                      4:  *
                      5:  * Redistribution and use in source and binary forms are permitted
                      6:  * provided that: (1) source distributions retain this entire copyright
                      7:  * notice and comment, and (2) distributions including binaries display
                      8:  * the following acknowledgement:  ``This product includes software
                      9:  * developed by the University of California, Berkeley and its contributors''
                     10:  * in the documentation or other materials provided with the distribution
                     11:  * and in all advertising materials mentioning features or use of this
                     12:  * software. Neither the name of the University nor the names of its
                     13:  * contributors may be used to endorse or promote products derived
                     14:  * from this software without specific prior written permission.
                     15:  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
                     16:  * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
                     17:  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
                     18:  */
                     19: 
                     20: #if defined(LIBC_SCCS) && !defined(lint)
                     21:        .asciz "@(#)strncpy.s   5.6 (Berkeley) 6/1/90"
                     22: #endif /* LIBC_SCCS and not lint */
                     23: 
                     24: /*
                     25:  * Copy string s2 over top of string s1.
                     26:  * Truncate or null-pad to n bytes.
                     27:  *
                     28:  * char *
                     29:  * strncpy(s1, s2, n)
                     30:  *     char *s1, *s2;
                     31:  */
                     32: #include "DEFS.h"
                     33: 
                     34: ENTRY(strncpy, R6)
                     35:        movl    12(ap),r6       # r6 = n
                     36:        bleq    done            # n <= 0
                     37:        movl    4(ap),r3        # r3 = s1
                     38:        movl    8(ap),r1        # r1 = s2
                     39: 1:
                     40:        movzwl  $65535,r2       # r2 = bytes in first chunk
                     41:        cmpl    r6,r2           # r2 = min(bytes in chunk, n);
                     42:        jgeq    2f
                     43:        movl    r6,r2
                     44: 2:
                     45:        subl2   r2,r6           # update n
                     46:        locc    $0,r2,(r1)      # '\0' found?
                     47:        jneq    3f
                     48:        subl2   r2,r1           # back up pointer updated by locc
                     49:        movc3   r2,(r1),(r3)    # copy in next piece
                     50:        tstl    r6              # run out of space?
                     51:        jneq    1b
                     52:        jbr     done
                     53: 3:                             # copy up to '\0' logic
                     54:        addl2   r0,r6           # r6 = number of null-pad bytes
                     55:        subl2   r0,r2           # r2 = number of bytes to move
                     56:        subl2   r2,r1           # back up pointer updated by locc
                     57:        movc3   r2,(r1),(r3)    # copy in last piece
                     58: 4:                             # null-pad logic
                     59:        movzwl  $65535,r2       # r2 = bytes in first chunk
                     60:        cmpl    r6,r2           # r2 = min(bytes in chunk, n);
                     61:        jgeq    5f
                     62:        movl    r6,r2
                     63: 5:
                     64:        subl2   r2,r6           # update n
                     65:        movc5   $0,(r3),$0,r2,(r3)# pad with '\0's
                     66:        tstl    r6              # finished padding?
                     67:        jneq    4b
                     68: done:
                     69:        movl    4(ap),r0        # return s1
                     70:        ret

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.