Return to pushl.s CVS log

Up to [Power 6/32 Unix Tahoe 4.2BSD] / cci / d / entry

Power 6/32 Unix version 1.2b

/*	PUSHL instruction test		*/
/*	  Privilege registers		*/

	.set	IPL,8
	.set	MAPEN,9
	.set	KSP,19

/*	  PSL fields			*/
	.set	IV,32
	.set 	T,16
	.set	N,8
	.set	Z,4
	.set	V,2
	.set	C,1

/*	  constants			*/
	.set	DISABLE,0
	.set 	ENABLE,1
	.set 	MAXPOSL,0x7fffffff
	.set	MAXNEGL,0x80000000
	.set	NEGVAL,0xfaaaaaaa
	.set	HIGH,31			/* highest interrupt priority	*/

	.globl	_pushlw
_pushlw:
	callf	$4,_setjmp	/* save context for error return */
	movab	_pushlw,_stpc	/* starting address of subtest	*/
	movl	$1,_subtst	/* subtest number */
	movl	$1,_no_opr	/* number of operands in use	*/
	movl	negval,_opr	/* first operand */
0:	bicpsw	$(IV|T)		/* disable exceptions		*/
/*								*/
pushml:				/* PUSH MEMORY ON STACK		*/
	movab	stk,r14		/* initialize stack pointer	*/
	movab   stk,r10
	bispsw	$(Z|V)		/* set z,v flags     	   	*/
	bicpsw  $(N|C)		/* clear n,c flag		*/
	pushl	negval		/* push negative value on stack	*/
	jgeq	error1		/* error if n flag not set	*/
	jeql	error1		/* error if z flag set		*/
	jvs	error1		/* error if v flag set	 	*/
	jcc	error1		/* error if c flag not set	*/
	jmp	1f
error1:	movpsl	_actual		/* actual = psl maybe incorrect	*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$2,_ercode	/* error code flag failure	*/
	jmp	*badrtn
1:	movab   (sp),r13
	decl	r10
	decl	r10
	decl	r10
	decl	r10
	cmpl	r10,r13		/* check if stack get decremented */
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r13,_actual	/* actual data */
	movl	r10,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$NEGVAL,(r14)	/* check if value get put on stack	*/
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	(r14),_actual	/* actual data */
	movl	$NEGVAL,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	negval,$NEGVAL	/* check if source get affected	*/
	jeql	pushrl
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$3,_ercode	/* error code operand miscompare */
	movl	negval,_actual	/* actual data */
	movl	$NEGVAL,_expected	/* expected data */
	jmp	*badrtn
pushrl:				/* PUSH REGISTER ON STACK	*/
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
ap2:	callf	$4,_setjmp	/* save context for error return */
	movab	ap2,_stpc	/* starting address of subtest	*/
	movl	$2,_subtst	/* subtest number */
	movl	$1,_no_opr	/* number of operands in use	*/
	movl	negval,_opr	/* first operand */
0:	movl	negval,r3	/* move negval to r3		*/
	bispsw	$(Z|V)		/* set z,v flags		*/
	bicpsw	$(N|C)		/* clear N,C flag		*/
	pushl	r3		/* push r3 on stack		*/
	jgeq	error2		/* error if n flag not set	*/
	jcc	error2		/* error if c flag not set	*/
	jeql	error2		/* error if z flag set		*/
	jvs	error2		/* error if v flag set  	*/
	jmp	1f
error2:	movpsl	_actual		/* actual = psl maybe incorrect	*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$2,_ercode	/* error code flag failure	*/
	jmp	*badrtn
1:	movab   (r14),r13
	decl	r10
	decl	r10
	decl	r10
	decl	r10
	cmpl	r10,r13		/* check if stack get declrement	*/
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r13,_actual	/* actual data */
	movl	r10,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$NEGVAL,(r14)	/* compare r14 to negval	*/
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	(r14),_actual	/* actual data */
	movl	$NEGVAL,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	r3,negval	/* make sure source unchanged   */
	jeql	zflag
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r3,_actual	/* actual data */
	movl	negval,_expected	/* expected data */
	jmp	*badrtn
zflag:				/* check z flag			*/
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
ap3:	callf	$4,_setjmp	/* save context for error return */
	movab	ap3,_stpc	/* starting address of subtest	*/
	movl	$3,_subtst	/* subtest number */
	movl	$1,_no_opr	/* number of operands in use	*/
	movl	$0,_opr	/* first operand */
0:	movl 	$0,r11		/* set r11 = 0			*/ 
	bispsw	$V		/* set v flags			*/
	bicpsw	$(Z|N|C)	/* clear Z,N,C flag		*/
	pushl	r11		/* push r11 on stack		*/
	jlss	error3		/* error if n flag set		*/
	jvs	error3		/* error if v flag set  	*/
	jneq	error3		/* error if z flag not set	*/
	jcc	error3		/* error if c flag not set	*/
	jmp	1f
error3:	movpsl	_actual		/* actual = psl maybe incorrect	*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$2,_ercode	/* error code flag failure	*/
	jmp	*badrtn
1:	movab   (r14),r13
	decl	r10
	decl	r10
	decl	r10
	decl	r10
	cmpl	r10,r13		/* check if stack get declrement	*/
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r13,_actual	/* actual data */
	movl	r10,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl 	$0,(r14)	/* compare r14 to 0		*/
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	(r14),_actual	/* actual data */
	movl	$0,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$0,r11		/* compare source to 0		*/
	jeql	p4
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$3,_ercode	/* error code operand miscompare */
	movl	r10,_actual	/* actual data */
	movl	$0,_expected	/* expected data */
	jmp	*badrtn

				/* PUSH LITERAL		*/
p4:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
ap4:	callf	$4,_setjmp	/* save context for error return */
	movab	ap4,_stpc	/* starting address of subtest	*/
	movl	$4,_subtst	/* subtest number */
	movl	$1,_no_opr	/* number of operands in use	*/
	movl	$0x3f,_opr	/* first operand */
0:	pushl	$0x3f		/* push literal value on stack	*/
	movab   (sp),r13
	decl	r10
	decl	r10
	decl	r10
	decl	r10
	cmpl	r10,r13		/* check if stack get decremented */
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r13,_actual	/* actual data */
	movl	r10,_expected	/* expected data */
	jmp	*badrtn
1:	cmpl	$0x3f,(r14)	/* check if value get put on stack	*/
	jeql	p5
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	(r14),_actual	/* actual data */
	movl	$0x3f,_expected	/* expected data */
	jmp	*badrtn

p5:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
ap5:	callf	$4,_setjmp	/* save context for error return */
	movab	ap5,_stpc	/* starting address of subtest	*/
	movl	$5,_subtst	/* subtest number */
	movl	$1,_no_opr	/* number of operands in use	*/
	movl	$0x11,_opr	/* first operand */
0:	pushl	$0x11		/* push literal value on stack	*/
	movab   (sp),r13
	decl	r10
	decl	r10
	decl	r10
	decl	r10
	cmpl	r10,r13		/* check if stack get decremented */
	jeql	1f
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	r13,_actual	/* actual data */
	movl	r10,_expected	/* expected data */
	jmp	*badrtn
1:	cmpl	$0x11,(r14)	/* check if value get put on stack	*/
	jeql	aldn
	bbs	$0,_scoplp,0b	/* if set scope loop on error	*/
	movl	$1,_ercode	/* error code data miscompare */
	movl	(r14),_actual	/* actual data */
	movl	$0x11,_expected	/* expected data */
	jmp	*badrtn


aldn:	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
	jmp	*return		/* good, return to monitor */

	jmp	*badrtn

/*	test data		*/
	.align	2
/*	stack			*/
	.space	40		/* 10 longwords for stack */
stk:	.long	0
negval:	.long	NEGVAL	

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.