Return to shll.s CVS log

Up to [Power 6/32 Unix Tahoe 4.2BSD] / cci / d / entry

Power 6/32 Unix version 1.2b

/*	SHLL instruction test		*/
/*	  Privilege registers		*/

	.set	IPL,8
	.set	MAPEN,9
	.set	KSP,19

/*	  PSL fields			*/
	.set	IV,32
	.set 	T,16
	.set	N,8
	.set	Z,4
	.set	V,2
	.set	C,1

/*	  constants			*/
	.set	DISABLE,0
	.set 	ENABLE,1
	.set	HIGH,31			/* highest interrupt priority	*/

	.globl	_shiftll
_shiftll:
	callf	$4,_setjmp	/* save context for error return */
	movab	_shiftll,_stpc	/* save starting address of subtest */
	movl	$1,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$1,_opr		/* first operand */
	movl	$0x55555555,_opr + 4 /* second operand */
0:	bicpsw	$(IV|T)		/* disable exceptions		*/
shftl:				/* SHIFT LEFT LONG FROM MEMORY TO REGISTER */
	movl	$0x55555555,srcloc	/* set srcloc = 0x55555555	*/
	movl	$0xaaaaaaaa,r4	/* set r4 = 0xaaaaaaaa		*/
	bispsw	$(Z|V)			/* set z,v flags		*/
	bicpsw	$(N|C)			/* clear n,c flag		*/
					/* data memory register		*/
	shll	$1,srcloc,r3		/* shift left 1 and put in r3	*/
	jgeq	error1			/* error if n flag not set	*/
	jcc	error1			/* error if c flag not set	*/
	jeql	error1			/* error if z flag still set	*/
	jvs	error1			/* error if v flag still set	*/
	jmp	1f
error1:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	cmpl	r3,r4		/* check result				*/
	jeql	1f		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	r3,_actual	/* actual data */
	movl	r4,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$0x55555555,srcloc	/* check if source get affected */
	jeql	s2		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$3,_ercode	/* error code operand miscompare */
	movl	srcloc,_actual	/* actual data */
	movl	$0x55555555,_expected	/* expected data */
	jmp	*badrtn
/*				  SHIFT LEFT LONG FROM REGISTER TO MEMORY */
s2:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
as2:	callf	$4,_setjmp	/* save context for error return */
	movab	as2,_stpc	/* save starting address of subtest */
	movl	$2,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$1,_opr		/* first operand */
	movl	r3,_opr + 4 /* second operand */
0:	movb	$1,temp		/* set temp = shift count		*/
	bispsw	$(N|Z|V)	/* set n,z,v flags			*/
	bicpsw  $C		/* clear C flag				*/
				/* memory reg memory			*/
	shll	temp,r3,dstloc	/* shift r3 left 1 and put in dstloc	*/
	jlss	error2		/* error if n,z,v flag still set	*/
	jeql	error2
	jvs	error2
	jcc	error2		/* error if c flag not set		*/
	jmp	1f
error2:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	cmpl 	dstloc,$0x55555554	/* check result			*/
	jeql	1f		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	dstloc,_actual	/* actual data */
	movl	$0x55555554,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	r3,$0xaaaaaaaa	/* make sure source unchanged		*/
	jeql	s3		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$3,_ercode	/* error code operand miscompare */
	movl	r3,_actual	/* actual data */
	movl	$0xaaaaaaaa,_expected	/* expected data */
	jmp	*badrtn
/*				  SHIFT LEFT LONG FROM MEMORY TO MEMORY */
s3:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
as3:	callf	$4,_setjmp	/* save context for error return */
	movab	as3,_stpc	/* save starting address of subtest */
	movl	$3,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$4,_opr		/* first operand */
	movl	srcloc,_opr + 4 /* second operand */
0:	movl	$4,r3		/* set r3 = shift count		*/
	bispsw	$(N|Z|V)	/* set n,z,v flags			*/
	bicpsw  $C		/* clear C flag				*/
				/* reg memory memory			*/
	shll	r3,srcloc,srcloc  /* shift and put result back in srcloc */
	jlss	error3		/* error if n flag still set		*/
	jeql	error3		/* error if z flag still set		*/
	jvs	error3
	jcc	error3		/* error if c flags not set		*/
	jmp	1f
error3:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	cmpl	srcloc,$0x55555550	/* check result			*/
	jeql	s4		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	srcloc,_actual	/* actual data */
	movl	$0x55555550,_expected	/* expected data */
	jmp	*badrtn
/*				  SPECIAL CASES				*/
/*					shift count = 0			*/
s4:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
as4:	callf	$4,_setjmp	/* save context for error return */
	movab	as4,_stpc	/* save starting address of subtest */
	movl	$4,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$0,_opr		/* first operand */
	movl	$0x55555555,_opr + 4 /* second operand */
0:	movl	$0x55555555,srcloc	/* set srcloc = 0x55555555	*/
	bispsw	$(N|Z|V)	/* set n,z,v flags			*/
	bicpsw  $C		/* clear C flag				*/
	shll	$0,srcloc,r3		/* shift left 0 and put in r3	*/
	jlss	error4			/* error if n flag still set	*/
	jeql	error4			/* error if z flag still set	*/
	jvs	error4			/* error if v flag still set	*/
	jcc	error4			/* error if c flag not set	*/
	jmp	1f
error4:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	cmpl	$0x55555555,r3		/* check result			*/
	jeql	1f		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	r3,_actual	/* actual data */
	movl	$0x55555555,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$0x55555555,srcloc	/* check if source get affected */
	jeql	s5		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$3,_ercode	/* error code operand miscompare */
	movl	srcloc,_actual	/* actual data */
	movl	$0x55555555,_expected	/* expected data */
	jmp	*badrtn
/*				  	shift count > 32		*/
s5:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
as5:	callf	$4,_setjmp	/* save context for error return */
	movab	as5,_stpc	/* save starting address of subtest */
	movl	$5,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$0,_opr		/* first operand */
	movl	$0x55555555,_opr + 4 /* second operand */
0:	movb	$33,temp	/* set shift count = 33			*/
	bispsw	$(N|C)		/* set n,c flags			*/
	bicpsw	$(V|Z)		/* clear z,v flag			*/
	shll	temp,r3,r5	/* shift r3 left 33 and put in r5	*/
	jlss	error5		/* error if n flag still set		*/
	jneq	error5		/* error if z flag not set		*/
	jvs	error5
	jcc	error5		/* error if c flags not set		*/
	jmp	1f
error5:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl 	r5,$0		/* check result				*/
	jeql	1f		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	r5,_actual	/* actual data */
	movl	$0,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	r3,$0x55555555	/* make sure source unchanged		*/
	jeql	s6		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$3,_ercode	/* error code operand miscompare */
	movl	r3,_actual	/* actual data */
	movl	$0x55555555,_expected	/* expected data */
	jmp	*badrtn

s6:
	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
as6:	callf	$4,_setjmp	/* save context for error return */
	movab	as6,_stpc	/* save starting address of subtest */
	movl	$6,_subtst	/* subtest number */
	movl	$2,_no_opr	/* number of operands in use */
	movl	$32,_opr		/* first operand */
	movl	$0xffffffff,_opr + 4 /* second operand */
0:	movb	$32,r6			/* set r6 = shift count		*/
	movl	$0xffffffff,srcloc	/* set srcloc = 0xffffffff	*/
	bispsw	$(N|C|V)		/* set n,c,v flags		*/
	bicpsw	$Z			/* clear z flag			*/
	shll	r6,srcloc,r3		/* shift left 32 and put in r3	*/
	jlss	error6			/* error if n flag set		*/
	jvs	error6			/* error if v flag set		*/
	jneq	error6			/* error if z flag not set	*/
	jcc	error6			/* error if c flag not set	*/
	jmp	1f
error6:	movpsl	_actual		/* actual = psl MAYBE 			*/
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$2,_ercode	/* error code flag failure */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	r3,$0		/* check result				*/
	jeql	1f		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$1,_ercode	/* error code data miscompare */
	movl	r3,_actual	/* actual data */
	movl	$0,_expected	/* expected data */
	jmp	*badrtn
1:	bicpsw  $Z
	cmpl	$0xffffffff,srcloc	/* check if source get affected */
	jeql	aldn		/* no error then continue */
	bbs	$0,_scoplp,0b	/* if set scope loop on error */
	movl	$3,_ercode	/* error code operand miscompare */
	movl	srcloc,_actual	/* actual data */
	movl	$0xffffffff,_expected	/* expected data */
	jmp	*badrtn


aldn:	bbs	$0,_force_lp,0b	/* if set loop on last subtest */
	jmp	*return

	
/*	test data		*/
	.align	2
srcloc:	.long	0
dstloc:	.long	0
temp:	.long	0

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.