Return to init1.x CVS log

Up to [Power 6/32 Unix Tahoe 4.2BSD] / cci / d / ioex

Power 6/32 Unix version 1.2b

/*	init.s								*/


/*	This file is a diagnostic version of locore.s.			*/
/*	It contains the following:					*/
/*	*system data area = scb, dump buffer, interrupt stack,		*/
/*	*system page table,user page tables,pcbs,iomap, & io buffers.	*/
/*									*/
/*	*system code = interrupt vectors, initialization of system data,*/
/*	*memory size calculation,initialization of SPT, zeroing of	*/
/*	*unused memory, & loading of SBR & SLR.				*/
/*	*								*/
/*	*at the end of this code, you are ready to go to virtual mode.	*/
/*	* --- GOOD LUCK!						*/


#include	"conf.h"
/*	privileged registers addresses	*/
#include	"prvreg.h"
	
/*	program status long word definition	*/
#include	"psl.h"	

/* 	page table entry definition		*/
#include	"pte.h"
	
/*	process control block offsets	*/
#include	"pcboffset.h"	

/*	fundamental constants for globl use	*/
#include	"const.h"	

/*	system control block offsets*/
#include	"scboffset.h"
/*	SPT offsets				*/
#include	"sptoffset.h"

/*	trap numbers*/
#include	"trap.h"	


#define V_TRAP		0
#define V_SYSCALL	4

	.set	HIGH,0x1f	/*mask for disabling all interrupts	*/
	.set	MCKVEC,4	/*scb offset for machinecheck vector	*/
	.set	NISP,2		/*no. of interrupt stack pages		*/
	.set	DONE,255	/*user process done code		*/

	.text

#include "pstorage.s"		/* PROCESSOR STORAGE AREA 		*/

	.globl	_Entry
_Entry:
	jmp	start
	.space	(1024-6)



/*		globl dump buffer to be used for communication		*/
/*		between tests & interrupt handlers, & other misc.	*/
/*		purposes.						*/
				
				/*physical page 3			*/

	.set	NLWU,32		/*no. of longwords already used		*/
				/*this must be changed when you define	*/
				/*additional variables below before	*/
				/*_dbuf					*/
	.globl	_restart
_restart:
	.space	4		/*contains restart address for restarting*/
				/*after power is restored (loaded by	*/
				/*power fail interrupt handler & used by*/
				/*CPU 2					*/	
/*	******************	*/
	.globl	_cyconf		/*  address : 0xc04  			*/
_cyconf:			/*  Cypher configuration pointer : 0xc06  */
	.space	4
	.space	4
/*	******************	*/

	.globl	_lastadd
_lastadd:
	.space	4		/*address of the last long word		*/

	.globl	_unused
_unused:
	.space	4		/*first unused page in system space	*/

	.globl	_ctlblk
_ctlblk:
	.long	0		/* pointer to SCB */

	.globl	_savvec0	/*save vectors area			*/
_savvec0:
	.space	4

	.globl	_savvec1	/*save vectors area			*/
_savvec1:
	.space	4

	.globl	_savvec2	/*save vectors area			*/
_savvec2:
	.space	4

	.globl	_savvec3	/*save vectors area			*/
_savvec3:
	.space	4

	.globl	_savvec4	/*save vectors area			*/
_savvec4:
	.space	4

	.globl	_savvec5	/*save vectors area			*/
_savvec5:
	.space	4
	.globl	_savvec6	/*save vectors area			*/
_savvec6:
	.space	4
	.globl	_savvec7	/*save vectors area			*/
_savvec7:
	.space	4

	.globl	_savvec8	/*save vectors area			*/
_savvec8:
	.space	4

testno: .long	0

	.globl	_dbuf		/*dump buffer left out of 1K		*/
	.globl	_r_no
_r_no:
	.long	0
	.globl	_pt_base
_pt_base:
	.long	0
	.globl	_saved_psl
_saved_psl:
	.long   0
	.globl	_saved_sp
_saved_sp:
	.long	0
	.globl	_saved_fp
_saved_fp:
	.long	0
	.globl	_p_ptr
_p_ptr:
	.long   0
	.globl	_ret_adr
_ret_adr:
	.long	0
	.globl	_exp_par0
_exp_par0:
	.long	0
	.globl	_exp_par1
_exp_par1:
	.long	0
	.globl	_exp_par2
_exp_par2:
	.long	0
	.globl	_exp_par3
_exp_par3:
	.long	0
	.globl	_act_par0
_act_par0:
	.long	0
	.globl	_act_par1
_act_par1:
	.long	0

	.globl	_IOpage
_IOpage:
	.long	0		/* Pointer 64K I/O pages */
#
#
#
	.globl	_proc_no
_proc_no:
	.long	0

	.globl	_clk_cnt
_clk_cnt:
	.long	0
_dbuf:
	.space	NBPG - (NLWU *4)
edbuf:


	.globl	_intstack	/* Interrupt stack			*/
_intstack:			/* Physical pages 4 & 5			*/
	.space	NISP*NBPG
eintstack:


	.set	SYSPTSIZE,512	/* No. of entries in SPT		*/
 
/*
	System Page Table -- physical page 6 & 7
*/ 
	.align	2
	.globl	_Sysmap
_Sysmap:
	.space	SYSPTSIZE*4 	/* 512 max pages allowed for system	*/
eSysmap:
	.globl	_Syssize
	.set	_Syssize,(eSysmap-_Sysmap)/4	/* should be SYSPTSIZE	*/
	
	.globl	_iomap		/* Physical page 8	*/
_iomap:	.space	1024		/* IOMAP - unused 	*/
	.globl	_eiomap
_eiomap:

	.globl	_pcb0		/* Physical page 9	*/
_pcb0:	.space	128		/*process control block 0		*/
	.globl	_pcb1
_pcb1:	.space 128		/*process control block 1		*/
	.globl	_pcb2
_pcb2:	.space 128		/*process control block 2		*/
	.globl	_pcb3
_pcb3:	.space 128		/*process control block 3		*/
	.globl	_pcb4
_pcb4:	.space 128		/*process control block 4		*/
	.globl	_pcb5
_pcb5:	.space 128		/*process control block 5		*/
	.globl	_pcb6
_pcb6:	.space 128		/*process control block 6		*/
	.globl	_pcb7
_pcb7:	.space 128		/*process control block 7		*/

/*
	*user #0 page tables -- P0PT, P1PT, P2PT			
	*physical memory     --  page10, 11, & 12  respectively
*/
	.align	2
	.globl	_u0p0pt
_u0p0pt:
	.space	1024		/*255 max pages for user #0 text	*/
	.globl	_u0p1pt
_u0p1pt:	
	.space	1024		/*255 max pages for user #0 data	*/
	.globl	_u0p2pt
_u0p2pt:	
	.space	1020		/*255 max pages for user #0 stack	*/
eu0p2pt:
	.space	4

/*
	*user #1 page tables -- P0PT, P1PT, P2PT			
	*physical memory     --  page13 ,14, & 15  respectively
*/
	.align	2
	.globl	_u1p0pt
_u1p0pt:
	.space	1024		/*255 max pages for user #1 text	*/
	.globl	_u1p1pt
_u1p1pt:	
	.space	1024		/*255 max pages for user #1 data	*/
	.globl	_u1p2pt
_u1p2pt:	
	.space	1020		/*255 max pages for user #1 stack	*/
eu1p2pt:
	.space	4


/*
	*user #2 page tables -- P0PT, P1PT, P2PT			
	*physical memory     --  page 16, 17 , & 18  respectively
*/
	.align	2
	.globl	_u2p0pt
_u2p0pt:
	.space	1024		/*255 max pages for user #2 text	*/
	.globl	_u2p1pt
_u2p1pt:	
	.space	1024		/*255 max pages for user #2 data	*/
	.globl	_u2p2pt
_u2p2pt:	
	.space	1020		/*255 max pages for user #2 stack	*/
eu2p2pt:
	.space	4


/*
	*user #3 page tables -- P0PT, P1PT, P2PT			
	*physical memory     --  page 19, 20 , & 21  respectively
*/
	.align	2
	.globl	_u3p0pt
_u3p0pt:
	.space	1024		/*255 max pages for user #3 text	*/
	.globl	_u3p1pt
_u3p1pt:	
	.space	1024		/*255 max pages for user #3 data	*/
	.globl	_u3p2pt
_u3p2pt:	
	.space	1020		/*255 max pages for user #3 stack	*/
eu3p2pt:
	.space	4

/*
	*user #4 thru 6 page tables
	*physical memory -- pages 22 thru 30
*/
	.globl	_u4p0pt
_u4p0pt:
	.space	(9*NBPG) - 4
eu6p2pt:
	.space	4

/*
	*user #7 page tables -- P0PT, P1PT, P2PT			
	*physical memory     --  page 31, 32 , & 33  respectively
*/
	.align	2
	.globl	_u7p0pt
_u7p0pt:
	.space	1024		/*255 max pages for user #7 text	*/
	.globl	_u7p1pt
_u7p1pt:	
	.space	1024		/*255 max pages for user #7 data	*/
	.globl	_u7p2pt
_u7p2pt:	
	.space	1020		/*255 max pages for user #7 stack	*/
eu7p2pt:
	.space	4

	.globl	_Ksp0		/* Page used for Kernel stack of user0 */
_Ksp0:	.space	1020
_Eksp0:	.long	0

	.globl	_Ksp1		/* Page used for Kernel stack of user1 */
_Ksp1:	.space	1020
_Eksp1:	.long	0

	.globl	_Ksp2		/* Page used for Kernel stack of user2 */
_Ksp2:	.space	1020
_Eksp2:	.long	0

	.globl	_Ksp3		/* Page used for Kernel stack of user3 */
_Ksp3:	.space	1020
_Eksp3:	.long	0

	.globl	_Ksp4		/* Page used for Kernel stack of user4 */
_Ksp4:	.space	1020
_Eksp4:	.long	0

	.globl	_Ksp5		/* Page used for Kernel stack of user5 */
_Ksp5:	.space	1020
_Eksp5:	.long	0

	.globl	_Ksp6		/* Page used for Kernel stack of user6 */
_Ksp6:	.space	1020
_Eksp6:	.long	0
#
#	I/O buffers
#
	.globl	_iob0
_iob0:	.space	1024
	.globl	_iob1
_iob1:	.space	1024
	.globl	_iob2
_iob2:	.space	1024
	.globl	_iob3
_iob3:	.space	1024
	.globl	_iob4
_iob4:	.space	1024
	.globl	_iob5
_iob5:	.space	1024

esysdata:

#include "scblock.s"		/* SYSTEM CONTROL BLOCK 		*/






#include	"evthandlers.s"	/*event handlers			*/

#define	ACBL(_n1,_n2,_n3,_n4) \
addl2	_n2,_n3;\
cmpl	_n3,_n1;\
bleq	_n4;



/*
	*INITIALIZATION CODE
	*
	* MME off; mode = k; IPL = 31; IS = 1
	*
*/

	.globl	start
start:
	mtpr	$0,$MME		/* Disable MME */
	movl	r0,tst_mask
	movab	_scb,r0
	andl2	$0x3ffffc00,r0
	mtpr	r0,$SCBB	/* Set SCBB  */
	mtpr	$0x1f,$IPL	/* Set IPL to HIGH */

	movpsl	r1
	andl2	$0x001f0000,r1		/* Mask out flags		*/
	cmpl	r1,$0x001f0000		/* modes = K & IPL = 31?	*/
	beql	1f
2:	movl	$1,r0
	movl	$0x041f0000,r2
	halt			/* PSL not initialized as expected	*/
1:
	movl	$_intstack+NISP*NBPG,r0
	andl2	$0x3fffffff,r0		/* Mask out bit 30,31 */
	mtpr	r0,$ISP			/* init. ISP		*/
	movl	r0,sp			/* in case we get exception	*/
	movab	(sp),fp			/* Initialize FP	  	*/
#
# 	Clear system data area all the way upto system code
# 	this includes dump buffer,interrupt stack,spt,iomap,pcbs,user 
# 	page tables, & io buffer area.
#
3:	
	movab	esysdata,r7
	movab	_restart,r6
1:	clrl	(r6)
	ACBL(r7,$4,r6,1b)
#
# 	Initialize System Page Table
#
5:
	clrl	r2
	movab	_Ksp6,r1	/* R1 = Last address in Kernel stack area */
	andl2	$0x3fffffff,r1	/* Mask out bit 30,31	*/
	shar	$PGSHIFT,r1,r1	/* Get page no. of last page of Kstacks  */
1:
	movl	r2,r11			/* Donot want to use orl3 */
	orl2	$PG_V|PG_KW,r11
	orl2	r11,_Sysmap[r2]
	aobleq	r1,r2,1b

	movab	esysdata,r1	/* R1 = Last address in system data area */
	andl2	$0x3fffffff,r1	/* Mask out bit 30,31	*/
	shar	$PGSHIFT,r1,r1	/* Get page no. of last system data addr  */
1:
	movl	r2,r11			/* Donot want to use orl3 */
	orl2	$PG_V|PG_KW|PG_NC,r11	/* Set I/O buffers non cachable */
	orl2	r11,_Sysmap[r2]
	aoblss	r1,r2,1b
#
#  	Map system text area 1 to 1, Kernel read/write.
#	For this to work, the label _etext must exist at the end 
#	of system code; Add in 4 more pages for data area used in C
#
	movab	_end + (NBPG-1),r1	/* Map text+data 1 to 1; Kernel R/W */
	andl3	$0x3ffffc00,r1,_IOpage
	addl2	$64*(1024),r1
	andl2	$0x3fffffff,r1
	shar	$PGSHIFT,r1,r1
1:
	movl	r2,r11
	orl2	$PG_V|PG_KW|PG_NC,r11	/* Kernel Read/Write, non_cachable */
	orl2	r11,_Sysmap[r2]
	aoblss	r1,r2,1b
#
# 	Map from here (1st unused page) to page 512 :
# 	   * invalid,no access, & virtual = physical
#
	movl	r2,_unused	/* Save first unused physical page no	*/
	movl	$LSP+1,r1
1:	movl	r2,_Sysmap[r2]
	aoblss	r1,r2,1b

sysrdy:
	movab	_Sysmap,r0
	mtpr	r0,$SBR      		/* Set SYSTEM BASE REG */
	mtpr	$_Syssize,$SLR
	orl2	$0xc0000000,r0
	mtpr	r0,$P0BR		/* Set P0BR */
	mtpr	$_Syssize,$P0LR

	movl	$CLOCK,r0
	movab	_Xclock,_scb[r0]	/* Set clock handler */

	movl	$BUSER,r0
	movab	_Buser,_scb[r0]		/* Set bus error handler */

	clrl	_bturn
	clrl	_bell
	clrl	_btime
	mtpr	$1,$IPL			/* Allow clock interrupt */
_bmore:
	cmpl	_btime,$0x5
	jeql	1f
	jmp	_bmore
1:	incl	_bell			/* No more bell */

	.globl	_ready
_ready:
	clrl	_proc_no
	mtpr	$1,$PACC
	mtpr	$1,$PADC
	mtpr	$1,$TBIA
	mtpr	$1,$CCK			/* Set Code Cache Key = 1 */
	mtpr	$1,$DCK			/* Set Data Cache Key = 1 */
	mtpr	$1,$MME			/* Enable MME */
	jmp	*$1f
1:
	movab	_pcb0,r0
	movab	_Eksp0,(r0)		/* Set PCB0_KSP */
	mfpr	$P0BR,PCB_P0BR(r0)	/* Set PCB0_P0BR */
	mfpr	$P0LR,PCB_P0LR(r0)	/* Set PCB0_P0LR */
	mtpr	r0,$PCBB		/* Init PCBB to PCB_0 */
	ldpctx				/* Just to switch to Kernel stack */
	mtpr 	$1,$IPL			/* Drop IPL to 0 */
	movl	(sp)+,r12		/* Pop unnecessary PC,PSL */
	movl	(sp)+,r11

	incl	_IOinit		/* Set flag, so bus err won't print */
	clrl	_Berr
#
#	The following tests are included : Tape, Udc, Vioc, Vddc.
#	Bit 0-3 correspond to Tape, Udc, Vioc, Vddc test. To disable
#	a particular test just set the corresponding bit to 1 before
#	start. For example, if only Vddc test to be run, set R0=7.
#	To run all, set R0 = 0.
#
1:
	clrl	_IOinit		/* Clear flag, so bus err will print */
	callf	$4,_xylog

2:
	movl	$0xcafebabe,r0
	halt
#
#	Real time clock Handler
#
	.align	2
	.globl	_Xclock
_Xclock:
	tstl	_bell			/* If set then just return */
	jneq	2f
	incl	_bturn
	cmpl	_bturn,$0x20
	jneq	2f
	pushl	$7
	callf	$8,_writec		/* Ring bell */
	incl	_btime
	clrl	_bturn
2:	rei

#
#	Bus error handler
#
	.align	2
	.globl	_Buser
_Buser:
	movab	(sp),-(sp)		/* Push pointer to error parameter */
	callf	$8,_buserror
	incl	_Berr
	movl	(sp)+,r0
	movl	(sp)+,r0
	rei


	.align	2
tst_mask:
	.long	0
_bell:	.long	0
_bturn: .long	0
_btime: .long	0
	.globl	_Multi
_Multi:  .long	0
	.globl	_Berr
_Berr:	.long	0
	.globl	_IOinit
_IOinit: .long	0
	.globl	_tape_ON
_tape_ON:
	.long	1
	.globl	_vioc_ON
_vioc_ON:
	.long	1
	.globl	_vddc_ON
_vddc_ON:
	.long	1

	.align	1
tmsg:	.ascii	"\nTape controller not found !\12\0"
vmsg:	.ascii	"\nVIOC controller not found !\12\0"
vdmsg:	.ascii	"\nVDDC controller not found !\12\0"
mmsg:	.ascii	"\nNot enough controllers for multiple interrupts test !\12\0"

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.