[BACK]Return to memset.s CVS log [TXT] [DIR] Up to [Plan 9 NeXT] / lucent / sys / src / libc / 68020
File:  [Plan 9 NeXT] / lucent / sys / src / libc / 68020 / memset.s
Revision 1.1.1.1 (vendor branch): download - view: text, annotated - select for diffs
Tue Apr 24 18:01:05 2018 UTC (8 years, 1 month ago) by root
Branches: lucent, MAIN
CVS tags: plan9, HEAD
Plan 9 NeXT

	TEXT	memset(SB), $0
	MOVL	n+8(FP), R0
	BLE	return
	MOVL	s1+0(FP), A1
	CLRL	R1
	MOVB	c+7(FP), R1
	BEQ	l1

/*
 * create 4 replicated copies
 * of the byte in R1
 */
	MOVL	R1, R2
	ASLL	$8, R2
	ORL	R2, R1
	MOVL	R1, R2
	SWAP	R2
	ORL	R2, R1

/*
 * quad-long-at-a-time set
 * destination allignment is not
 * very important.
 */
l1:
	SUBL	$16, R0
	BLT	l2
	MOVL	R1, (A1)+
	MOVL	R1, (A1)+
	MOVL	R1, (A1)+
	MOVL	R1, (A1)+
	BRA	l1

/*
 * cleanup byte-at-a-time
 */
l2:
	ADDL	$15, R0
	BLT	return
l3:
	MOVB	R1, (A1)+
	SUBL	$1, R0
	BGE	l3

return:
	MOVL	s1+0(FP),R0
	RTS
unix.superglobalmegacorp.com

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.