--- nono/configure.ac	2026/04/29 17:05:26	1.1.1.15
+++ nono/configure.ac	2026/04/29 17:05:51	1.1.1.19
@@ -52,11 +52,15 @@ AC_DEFUN([ADD_CC_WARN_IF],[
 	AC_MSG_CHECKING([whether cc accepts $1])
 	old_CFLAGS="${CFLAGS}"
 	CFLAGS="${CFLAGS} -Werror $1"
-	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
+	AC_COMPILE_IFELSE([
+		AC_LANG_PROGRAM([], [])
+	], [
 		AC_MSG_RESULT([yes])
 		eval `echo cc_has$1=yes | sed -e 's/-/_/g'`
-		WARNFLAGS_C="${WARNFLAGS_C} $1",
-		AC_MSG_RESULT([no]))
+		WARNFLAGS_C="${WARNFLAGS_C} $1"
+	], [
+		AC_MSG_RESULT([no])
+	])
 	CFLAGS="${old_CFLAGS}"
 ])
 ADD_CC_WARN_IF(-Wcast-qual)
@@ -81,11 +85,15 @@ AC_DEFUN([ADD_CXX_WARN_IF],[
 	AC_MSG_CHECKING([whether c++ accepts $1])
 	old_CXXFLAGS="${CXXFLAGS}"
 	CXXFLAGS="${CXXFLAGS} -Werror $1"
-	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
+	AC_COMPILE_IFELSE([
+		AC_LANG_PROGRAM([], [])
+	], [
 		AC_MSG_RESULT([yes])
 		eval `echo cxx_has$1=yes | sed -e 's/-/_/g'`
-		WARNFLAGS_CXX="${WARNFLAGS_CXX} $1",
-		AC_MSG_RESULT([no]))
+		WARNFLAGS_CXX="${WARNFLAGS_CXX} $1"
+	], [
+		AC_MSG_RESULT([no])
+	])
 	CXXFLAGS="${old_CXXFLAGS}"
 ])
 ADD_CXX_WARN_IF(-Wcast-qual)
@@ -103,6 +111,8 @@ fi
 ADD_CXX_WARN_IF(-Wstring-conversion)
 ADD_CXX_WARN_IF(-Wsuggest-destructor-override)
 ADD_CXX_WARN_IF(-Wsuggest-override)
+# gcc14 が C++14 に対しても C++20 のエラーを出そうとする。は??
+ADD_CXX_WARN_IF(-Wno-template-id-cdtor)
 ADD_CXX_WARN_IF(-Wtype-limits)
 ADD_CXX_WARN_IF(-Wvla-extension)
 AC_SUBST([WARNFLAGS_CXX])
@@ -176,6 +186,7 @@ AS_IF([test x"${enable_neon}" != x"no"],
 # Checks for libraries.
 
 # Checks for header files.
+AC_CHECK_HEADERS([alsa/asoundlib.h])
 AC_CHECK_HEADERS([bsd/bsd.h])
 AC_CHECK_HEADERS([bsd/stdio.h])
 AC_CHECK_HEADERS([byteswap.h])
@@ -183,6 +194,8 @@ AC_CHECK_HEADERS([endian.h])
 AC_CHECK_HEADERS([kqueue/sys/event.h])
 AC_CHECK_HEADERS([pthread_np.h])
 AC_CHECK_HEADERS([sched.h])
+AC_CHECK_HEADERS([sndio.h])
+AC_CHECK_HEADERS([sys/audioio.h])
 AC_CHECK_HEADERS([sys/cpuset.h])
 AC_CHECK_HEADERS([sys/endian.h])
 AC_CHECK_HEADERS([sys/event.h])
@@ -286,6 +299,28 @@ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 		AC_MSG_RESULT(no)
 	])
 
+AC_MSG_CHECKING(for __builtin_bitreverse16)
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
+	[[
+		return __builtin_bitreverse16(1);
+	]])], [
+		AC_MSG_RESULT(yes)
+		AC_DEFINE(HAVE___BUILTIN_BITREVERSE16)
+	], [
+		AC_MSG_RESULT(no)
+	])
+
+AC_MSG_CHECKING(for __builtin_bitreverse32)
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
+	[[
+		return __builtin_bitreverse32(1);
+	]])], [
+		AC_MSG_RESULT(yes)
+		AC_DEFINE(HAVE___BUILTIN_BITREVERSE32)
+	], [
+		AC_MSG_RESULT(no)
+	])
+
 AC_MSG_CHECKING(for __builtin_bswap16)
 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 	[[
@@ -898,8 +933,10 @@ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 		AC_MSG_RESULT(yes)
 		AC_DEFINE(HAVE_HOSTNET_AFPACKET)
 		AC_SUBST(HOSTNET_AFPACKET, yes)
+		netdriver_afpacket=yes
 	], [
 		AC_MSG_RESULT(no)
+		netdriver_afpacket=no
 	])
 
 AC_MSG_CHECKING(for tap(4))
@@ -932,43 +969,69 @@ if test x"$ac_cv_header_net_bpf_h" = xye
 	AC_MSG_RESULT([yes])
 	AC_DEFINE([HAVE_HOSTNET_BPF])
 	AC_SUBST([HOSTNET_BPF], [yes])
+	netdriver_bpf=yes
 else
 	AC_MSG_RESULT([no])
+	netdriver_bpf=no
 fi
 
 #
 # Other libraries
 #
 
-# CHECK_LIB($1=name, $2=libs, $3=include, $4=src)
-AC_DEFUN([CHECK_LIB], [
+dnl # MY_CHECK_LIB($1=name, $2=libs, $3=include, $4=src)
+dnl #  name は変数名に付けるライブラリ名 ("libslirp" とか "libiconv" とか)
+dnl #  libs はライブラリ引数 ("-lslirp" とか)
+dnl #  include, src は検出用のヘッダとソース片。
+dnl #  ただし src は実行可能で害のないものを指定すること。
+dnl # PATHS からライブラリを探してそのパスとかをセットする。
+dnl #  has_${name}=<yes|no>
+dnl #  $CPPFLAGS_${name}=...
+dnl #  $LIBS_${name}=...
+AC_DEFUN([MY_CHECK_LIB], [
 	AC_MSG_CHECKING([for $1])
+	old_CPPFLAGS=${CPPFLAGS}
+	old_LIBS=${LIBS}
 	for path in ${PATHS}; do
-		old_CPPFLAGS=${CPPFLAGS}
-		old_LIBS=${LIBS}
 		case ${path} in
 		 none)
-			LIBS="${LIBS} $2"
+			LIBS="$2"
 			;;
 		 *)
-			CPPFLAGS="${CPPFLAGS} -I${path}/include"
-			LIBS="${LIBS} -L${path}/lib $2"
+			CPPFLAGS="-I${path}/include"
+			LIBS="-L${path}/lib $2"
 			;;
 		esac
 		AC_LINK_IFELSE([AC_LANG_PROGRAM([$3], [$4])], [
 			has_$1=yes
+
+			dnl リンクできれば -Wl,-R が必要か調べる。
+			AC_RUN_IFELSE([AC_LANG_SOURCE([[
+				$3
+				int main() {
+					$4;
+					return 0;
+				}
+			]])], [
+				dnl 実行できれば追加しなくていい。
+			], [
+				LIBS="-L${path}/lib -Wl,-R,${path}/lib $2"
+			])
+
 			break
 		], [
 			has_$1=no
 		])
-		CPPFLAGS=${old_CPPFLAGS}
-		LIBS=${old_LIBS}
 	done
 	if test x"${has_$1}" = x"yes"; then
 		AC_MSG_RESULT([yes])
+		CPPFLAGS_$1=${CPPFLAGS}
+		LIBS_$1=${LIBS}
 	else
 		AC_MSG_RESULT([no])
 	fi
+	CPPFLAGS=${old_CPPFLAGS}
+	LIBS=${old_LIBS}
 ])
 
 PATHS="none /usr/pkg /usr/local"
@@ -1007,6 +1070,100 @@ AC_CHECK_LIB(z, gzclose,
 *** If use use Ubuntu, sudo apt install zlib1g-dev])]
 )
 
+# libslirp
+AC_ARG_WITH([libslirp],
+	[AS_HELP_STRING([--without-libslirp],
+		[disable usermode network (using SLIRP)])],
+	[],
+	[with_libslirp=yes])
+
+AS_IF([test "x$with_libslirp" != "xno"], [
+	MY_CHECK_LIB([libslirp], [-lslirp], [
+		#include <slirp/libslirp.h>
+	], [
+		slirp_version_string();
+	])
+	if test x"${has_libslirp}" = x"yes"; then
+		AC_DEFINE([HAVE_HOSTNET_SLIRP])
+		AC_SUBST([HOSTNET_SLIRP], [yes])
+		AC_SUBST([CPPFLAGS_SLIRP], [${CPPFLAGS_libslirp}])
+		AC_SUBST([LIBS_SLIRP], [${LIBS_libslirp}])
+	else
+		AC_MSG_ERROR([*** libslirp is not found.
+*** If use use pkgsrc, install net/libslirp.
+*** If you use Ubuntu, sudo apt install libslirp-dev.
+*** Or specify --without-libslirp (it disables hostnet-driver=usermode).])
+	fi
+], [
+	AC_SUBST([HOSTNET_SLIRP], [no])
+])
+
+# ALSA
+case "${host_os}" in
+ linux*)
+	default_alsa=yes
+	;;
+ *)
+	default_alsa=no
+	;;
+esac
+AC_ARG_WITH([alsa],
+	[AS_HELP_STRING([--with-alsa],
+		[enable ALSA support (default:yes on Linux, otherwise no)])],
+	[with_alsa=${withval}],
+	[with_alsa=${default_alsa}])
+sounddriver_alsa=no
+if test x"${with_alsa}" = xyes; then
+	AC_CHECK_LIB(asound, snd_pcm_open,
+		[has_asound=yes],
+		[has_asound=no])
+	if test x"${ac_cv_header_alsa_asoundlib_h}" = xyes -a \
+	        x"${ac_cv_lib_asound_snd_pcm_open}" = xyes; then
+		AC_DEFINE([HAVE_HOSTSOUND_ALSA])
+		AC_SUBST([HOSTSOUND_ALSA], [yes])
+		LIBS_SOUND="${LIBS_SOUND} -lasound"
+		sounddriver_alsa=yes
+	else
+		AC_MSG_ERROR([*** <alsa/asoundlib.h> or libasound not found.
+*** If you use Ubuntu, sudo apt install libasound2-dev.
+*** Or specify --without-alsa (it disables hostsound-driver=alsa).])
+	fi
+fi
+
+# NetBSD audio
+if test x"${ac_cv_header_sys_audioio_h}" = xyes; then
+	AC_MSG_CHECKING(for AUDIO_GETINFO)
+	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
+		#include <sys/ioctl.h>
+		#include <sys/audioio.h>
+		#include <unistd.h>
+	], [
+		struct audio_info info;
+		AUDIO_INITINFO(&info);
+		ioctl(0, AUDIO_GETINFO, &info);
+	])], [
+		AC_MSG_RESULT([yes])
+		AC_DEFINE([HAVE_HOSTSOUND_NETBSD])
+		AC_SUBST([HOSTSOUND_NETBSD], [yes])
+		sounddriver_netbsd=yes
+	], [
+		AC_MSG_RESULT([no])
+		sounddriver_netbsd=no
+	])
+fi
+
+# OpenBSD sndio
+if test x"${ac_cv_header_sndio_h}" = xyes; then
+	AC_DEFINE([HAVE_HOSTSOUND_SNDIO])
+	AC_SUBST([HOSTSOUND_SNDIO], [yes])
+	LIBS_SOUND="${LIBS_SOUND} -lsndio"
+	sounddriver_sndio=yes
+else
+	sounddriver_sndio=no
+fi
+
+AC_SUBST([LIBS_SOUND], [${LIBS_SOUND}])
+
 # wxWidgets
 AC_ARG_WITH([gui],
 	[AS_HELP_STRING([--without-gui], [disable GUI support])],
@@ -1041,20 +1198,37 @@ AS_IF([test "x$with_gui" != xno], [
 		wxlibs=`$wxconfig --libs`
 
 		case "${host_os}" in
-		 netbsd*)
-			# rpath。どうしたもんだかこれ
-			wxlibs=[`echo $wxlibs | sed -e 's/-L\([^ ]*\) /-L\1 -Wl,-R,\1 /'`]
-			;;
-
 		 darwin*)
 			# XXX -framework AudioToolbox が指定されているとリンカがこけるorz
 			wxlibs=[`echo $wxlibs | sed -e 's/-framework AudioToolbox//'`]
 			;;
 		esac
 
+		dnl -Wl,-R が必要か調べる。
+		AC_MSG_CHECKING([whether wx-config requires -Wl,-R])
+		old_CPPFLAGS="${CPPFLAGS}"
+		old_LIBS="${LIBS}"
+		CPPFLAGS="${CPPFLAGS} ${wxcppflags}"
+		LIBS="${LIBS} ${wxlibs}"
+		AC_RUN_IFELSE([AC_LANG_SOURCE([[
+			#include <wx/wx.h>
+			int main() {
+				wxInitializer init;
+				return !init;
+			}
+		]])], [
+			dnl 実行できれば追加しなくていい。
+			AC_MSG_RESULT([no])
+		], [
+			AC_MSG_RESULT([yes])
+			wxlibs=[`echo $wxlibs | sed -e 's/-L\([^ ]*\) /-L\1 -Wl,-R,\1 /'`]
+		])
+		CPPFLAGS="${old_CPPFLAGS}"
+		LIBS="${old_LIBS}"
+
 		AC_SUBST([WITH_GUI], [yes])
-		AC_SUBST([WXWIDGETS_CPPFLAGS], [$wxcppflags])
-		AC_SUBST([WXWIDGETS_LIBS], [$wxlibs])
+		AC_SUBST([CPPFLAGS_WXWIDGETS], [$wxcppflags])
+		AC_SUBST([LIBS_WXWIDGETS], [$wxlibs])
 	fi
 
 	# gettext
@@ -1068,25 +1242,19 @@ AS_IF([test "x$with_gui" != xno], [
 	AC_SUBST([WITH_GUI], [no])
 ])
 
-# nono 本体のチェックはここまで。
-nono_CPPFLAGS=${CPPFLAGS}
-nono_LIBS=${LIBS}
-AC_SUBST([NONO_CPPFLAGS], [${nono_CPPFLAGS}])
-AC_SUBST([NONO_LIBS], [${nono_LIBS}])
-
 # iconv は util/ でのみ必要。
-CPPFLAGS=
-LIBS=
-CHECK_LIB([libiconv], [-liconv], [
+MY_CHECK_LIB([libiconv], [-liconv], [
 	#include <iconv.h>
 ], [
 	iconv_open("", "");
 ])
+AC_SUBST([CPPFLAGS_ICONV], [${CPPFLAGS_libiconv}])
+AC_SUBST([LIBS_ICONV], [${LIBS_libiconv}])
 
 if test x"${has_libiconv}" = x"yes"; then
 	AC_MSG_CHECKING(whether iconv needs const)
 	old_CPPFLAGS="${CPPFLAGS}"
-	CPPFLAGS="${CPPFLAGS} -Werror"
+	CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_libiconv} -Werror"
 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 			#include <iconv.h>
 		]], [[
@@ -1101,17 +1269,35 @@ if test x"${has_libiconv}" = x"yes"; the
 	CPPFLAGS="${old_CPPFLAGS}"
 fi
 
-iconv_CPPFLAGS=${CPPFLAGS}
-iconv_LIBS=${LIBS}
-AC_SUBST([ICONV_CPPFLAGS], [${iconv_CPPFLAGS}])
-AC_SUBST([ICONV_LIBS], [${iconv_LIBS}])
-
-AC_CONFIG_FILES([Makefile.cfg
-	host/Makefile
-	wx/Makefile
-	util/mkcgrom/Makefile
-	util/ttfext/Makefile
-	util/viewcgrom/Makefile
-])
+AC_CONFIG_FILES([Makefile.cfg])
 AC_CONFIG_HEADERS([config-nono.h])
 AC_OUTPUT
+
+# サマリを表示
+echo ""
+echo "Configuration summary:"
+echo -n "HostNet supports:			"
+if test x"$netdriver_afpacket" = xyes; then
+	echo -n " afpacket"
+fi
+if test x"$netdriver_bpf" = xyes; then
+	echo -n " bpf"
+fi
+if test x"$has_libslirp" = xyes; then
+	echo -n " slirp"
+fi
+if test x"$netdriver_tap" = xyes; then
+	echo -n " tap"
+fi
+echo ""
+echo -n "HostSound supports:			"
+if test x"$sounddriver_alsa" = xyes; then
+	echo -n " alsa"
+fi
+if test x"$sounddriver_netbsd" = xyes; then
+	echo -n " netbsd"
+fi
+if test x"$sounddriver_sndio" = xyes; then
+	echo -n " sndio"
+fi
+echo ""