Return to bold.icn CVS log

Up to [Research Unix] / researchv10dc / cmd / icon / ipl / source

researchv10 Dan Cross

#	BOLD
#
#	Produce bold and underscored text for printing
#
#	Ralph E. Griswold
#
#	Last modified 5/2/86
#

procedure bold(s)
   local c
   static labels, trans, max
   initial {
      labels := "1"
      trans := repl("1\b",4) || "1"
      max := *labels
      trans := bold(string(&lcase))
      labels := string(&lcase)
      max := *labels
      }
   if *s <= max then
      return map(left(trans,9 * *s),left(labels,*s),s)
   else return bold(left(s,*s - max)) ||
      map(trans,labels,right(s,max))
end

procedure uscore(s)
   static labels, trans, max
   initial {
      labels := "1"
      trans := "_\b1"
      max := *labels
      trans := uscore(string(&lcase))
      labels := string(&lcase)
      max := *labels
      }
   if *s <= max then
      return map(left(trans,3 * *s),left(labels,*s),s)
   else return uscore(left(s,*s - max)) ||
      map(trans,labels,right(s,max))
end

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.