Return to cpp.ed CVS log

Up to [Research Unix] / researchv9 / X11 / src / X.V11R1 / util / makedepend

researchv9-SUN3(old)

#
# $Header: /var/lib/cvsd/repos/research/researchv9/X11/src/X.V11R1/util/makedepend/cpp.ed,v 1.1.1.1 2018/04/24 17:22:00 root Exp $
#
# $Locker $
#
/struct symtab stab/d
/struct symtab \*defloc;/d
/struct symtab \*udfloc;/d
/struct symtab \*incloc;/d
/struct symtab \*ifloc;/d
/struct symtab \*elsloc;/d
/struct symtab \*eifloc;/d
/struct symtab \*ifdloc;/d
/struct symtab \*ifnloc;/d
/struct symtab \*ysysloc;/d
/struct symtab \*varloc;/d
/struct symtab \*lneloc;/d
/struct symtab \*ulnloc;/d
/struct symtab \*uflloc;/d
/^sayline(/s/$/	DELETED/p
.,/^}/d
/^unfill(/s/$/	DELETED/p
.-1,/^}/d
/^doincl(/s/$/	DELETED/p
.-1,/^}/d
/^equfrm(/s/$/	DELETED/p
.,/^}/d
/^dodef(/s/$/	DELETED/p
.-1,/^}/d
/^control(/s/$/	DELETED/p
.-1,/^}/d
/^savestring(/s/$/	DELETED/p
.-1,/^}/d
/^stsym(/s/$/	DELETED/p
.-1,/^}/d
/^ppsym(/s/$/	DELETED/p
.-1,/^}/d
/^yyerror(/s/$/	DELETED/p
.,/^}/d
/^ppwarn(/s/$/	DELETED/p
.,/^}/d
/^lookup(/s/$/	DELETED/p
.-1,/^}/d
/^subst(/s/$/	DELETED/p
.-1,/^}/d
/^trmdir(/s/$/	DELETED/p
.-1,/^}/d
/^copy(/s/$/	DELETED/p
.-1,/^}/d
/^pperror(/s/$/	DELETED/p
.,/^}/d
/^main(/s/$/	CHANGED to cpp_varsetup(argc,argv)/p
.c
cpp_varsetup(argc,argv)
.
/^strdex(/s/$/	DELETED/p
.-1,/^}/d
/^ for(i=1; i<argc; i++)/s/$/	To the end DELETED/p
.,$c
}
.
/^dump(/s/$/	DELETED/p
.,/^}/c
dump() { log_fatal("dump\n"); }
.
/^refill(/s/$/	DELETED/p
.,/^}/c
refill() { log_fatal("refill\n"); }
.
/^slookup(/s/$/	DELETED/p
.-1,/^}/c
static struct symtab *slookup() { log_fatal("slookup\n"); }
.
w
q

This archive runs on limited infrastructure. Preserving old code on modern bandwidth. Automated agents are requested to crawl responsibly.